Outil de tri de liste

Salut à tous.

En effet collatéral de la discussion sur les introductions modifiées de MacSoup,
si vous établissez des listes (en /list/ et non pas en suite de lignes) de
"maximes", vous serez sans doute intéressés par ce script de tri très puissant
et très "velu", s'inspirant du célèbre algorithme "Quicksort" et ici transposé
pour Applescript par deux pointures es-programmation et scriptage,
Kevin Bradley & Nigel Garvey.

Ce script, par nature s'utilise depuis l'Editeur de script, alors NE PAS TOUCHER
AU CODE, SVP, mais simplement :

mettez votre liste à trier en vrac dans la variable / A_list / et executez le
script, puis récupérez le résultat trié dans la fenêtre de réponse en bas.

Si vraiment vous êtes NULS au point de ne pas savoir vous en servir, je
l'envelopperai dans une applet passant par le presse-papier, mais franchement je
n'ai pas que ça à faire, sans dec !

J'ai mis un FU2 vers r.comp.sys.mac.programmation
mais j'imagine que personne n'en voudra…

HTH, et bien cordialement,

∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞
set A_list to {"eeeeee", "wwwwwww", "hhhhhhh", "rrrrrrr", "bbbbbbb"}
-- votre liste entre les accolades ci-dessus, ne pas toucher au reste !

set SL to quickSort(A_list, "a") -- "a" = tri ascendant, "d" = tri descendant

on quickSort(theList, theDirection) --by Kevin Bradley & Nigel Garvey
--public routine, called from your script
script bs
property alist : theList

on Qsort(leftIndex, rightIndex)
--private routine called by quickSort.
--do not call from your script!
if rightIndex > leftIndex then
set thePivot to ((rightIndex - leftIndex) div 2) + leftIndex
set newPivot to Qpartition(leftIndex, rightIndex, thePivot)
set theList to Qsort(leftIndex, newPivot - 1)
set theList to Qsort(newPivot + 1, rightIndex)
end if
end Qsort

on Qpartition(leftIndex, rightIndex, thePivot)
--private routine called by quickSort.
--do not call from your script!
set pivotValue to item thePivot of bs's alist
set item thePivot of bs's alist to item rightIndex of bs's alist
set tempIndex to leftIndex
repeat with pointer from leftIndex to (rightIndex - 1)
set temp to item pointer of bs's alist
-- temp is set here to save getting the item twice.
if not (temp > pivotValue) then
set item pointer of bs's alist to item tempIndex of bs's alist
set item tempIndex of bs's alist to temp
set tempIndex to tempIndex + 1
end if
end repeat
set item rightIndex of bs's alist to item tempIndex of bs's alist
set item tempIndex of bs's alist to pivotValue --temp
return tempIndex
end Qpartition
end script

if length of bs's alist > 1 then bs's Qsort(1, length of bs's alist)

if theDirection is "d" then return the reverse of bs's alist
return bs's alist
end quickSort
∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞∞

--
J. B.